mirror of
https://github.com/KRTirtho/spotube.git
synced 2026-11-04 10:13:59 +00:00
8ab9463c9a
- Flatpak manifest (GNOME 51, libvlc built from source) installing from a new portable spotube-linux-<version>-<arch>.tar.xz, shared with the AUR package - Release workflow builds and attaches the Linux tarballs for x86_64 and aarch64 - Package files are JMustache templates rendered by :composeApp:renderPackaging<Target> with the version, release asset checksums and git-cliff release notes; the metainfo release history is generated - Publish workflow (workflow_dispatch, release tag input) renders once and pushes to Flathub, the AUR, WinGet (PR from team-spotube/winget-pkgs) and Chocolatey - Chocolatey and WinGet updated for the NSIS installer
33 lines
1.4 KiB
Plaintext
33 lines
1.4 KiB
Plaintext
# Maintainer: Kingkor Roy Tirtho <krtirho@gmail.com>
|
|
pkgname=spotube-bin
|
|
pkgver={{version}}
|
|
pkgrel={{pkgrel}}
|
|
pkgdesc="Open source, plugin powered music streaming client"
|
|
arch=(x86_64 aarch64)
|
|
url="https://spotube.org"
|
|
license=('AGPL-3.0-or-later')
|
|
# libvlc + plugins for playback (FFmpeg demux/decode, GnuTLS for HTTPS streams, PulseAudio/PipeWire output),
|
|
# WebKitGTK 4.1 for the webview, and the X11/GL/ALSA libraries the AWT/Skiko natives link
|
|
depends=(
|
|
'libvlc' 'vlc-plugins-base' 'vlc-plugin-ffmpeg' 'vlc-plugin-gnutls' 'vlc-plugin-pulse'
|
|
'webkit2gtk-4.1' 'gtk3' 'glib2' 'dbus' 'alsa-lib' 'libglvnd' 'fontconfig' 'freetype2'
|
|
'libx11' 'libxext' 'libxi' 'libxrender' 'libxtst' 'zlib'
|
|
)
|
|
provides=('spotube')
|
|
conflicts=('spotube')
|
|
options=('!strip' '!debug')
|
|
source_x86_64=("https://github.com/team-spotube/spotube/releases/download/v${pkgver}/spotube-linux-${pkgver}-x86_64.tar.xz")
|
|
source_aarch64=("https://github.com/team-spotube/spotube/releases/download/v${pkgver}/spotube-linux-${pkgver}-aarch64.tar.xz")
|
|
sha256sums_x86_64=('{{artifacts.linuxX86_64.sha256}}')
|
|
sha256sums_aarch64=('{{artifacts.linuxAarch64.sha256}}')
|
|
|
|
package() {
|
|
cd "spotube-linux-${pkgver}-${CARCH}"
|
|
|
|
install -dm755 "${pkgdir}/opt" "${pkgdir}/usr/bin" "${pkgdir}/usr/share"
|
|
cp -a app "${pkgdir}/opt/spotube"
|
|
cp -a share/. "${pkgdir}/usr/share/"
|
|
ln -s /opt/spotube/spotube "${pkgdir}/usr/bin/spotube"
|
|
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
|
|
}
|